Social Structures and Speeding Trucks: A Simulation with Experimentation

Michael A. Faia

This study develops a Maple simulation and exploits opportunities for experimenting with it; additional examples are available at

http://morton.wm.edu/public html/index.html.

The simulation involves truck transportation, incentives for speeding, and the efficacy of various ways of controlling speeding. After setting several initial structural conditions, we show how these conditions make possible an estimate of operating costs per trip as a function of speed. Next, we suggest ways in which the total cost function, operating as a feedback mechanism, might influence a driver’s incentives for speeding or slowing down, or a firm’s incentives for encouraging or discouraging speeding. Finally, a series of experiments, only partially shown herein and involving the probability and severity of traffic citations, suggests why maximum deterrence of speeding requires a judicious combination of sanction severity and sanction probability.

Reading Ouellet (1994), we learn that the typical trucker logs 60 to 70 hours per week; that he works “at a steady clip” whether paid by the hour or by the load; that there are subtle pressures that lead to excessive speed, e.g., “drivers often jockey one another for position on the road and by the loading dock, as a minute or two lead to the next job ... can save an hour or two of waiting time.” We therefore seek conditions under which a speed in excess of 65 to 70 miles per hour would appear to be “rational.” Are there circumstances under which, say, 80 m.p.h. would seem rational? How would law enforcement attempt to manipulate these circumstances? Here, of course, the word rational means cost-minimizing, or profit-maximizing.

The user, early in this simulation, may experiment with the first four input values, k1, x[1], k3, and k4. Later on, we encounter additional opportunities for experimentation based on further theoretical considerations.

Structure

First, we insert a baseline operating cost, in dollars per mile, for a given type of truck. By baseline, we mean all costs involved in paying for and maintaining a truck, worked out on a per-mile basis, but without considering ways in which costs are raised by driver behavior, e.g., high operating speeds, mechanical abuse, etc., or by traffic citations.

Standard cost per mile, in dollars:

   > k1 := 1/3;

k1 := \frac{1}{3}

Truck operating costs increase exponentially with average speed, due to increased fuel consumption and increased depreciation. We estimate this additional per/mile cost to be a certain multiplier of a dollar: the speed in m.p.h., called v, which we will first adjust with an exponent and then divide by, say, 1000 or some other large “standard.” This latter value itself may need to be adjusted from time to time to reflect changing costs of fuel, depreciation, etc. We begin with an equation such as that given immediately below as a plausible way of capturing this variable.

   > x[1] := (v^(8/5))/(4 * (10^3)); # additional velocity factor

x_{1} := \frac{1}{4000} v^{8/5}

The next several expressions should be fairly clear. They, too, are subject to change. We begin by considering the situation of drivers who have an hourly pay rate; such drivers, according to Ouellet, are in a very different situation from those who receive piece-work payment. The hourly wage, initialized below, assumes that for at least part of a lengthy trip, two drivers must be paid, so that the value assigned to k3 is a weighted average.

   > k3 := 3715/100; # drivers' hourly wage

k3 := \frac{743}{20}

   > k4 := 600; # trip length, miles

k4 := 600

Now we obtain a provisional total cost, for trips of this type. The total cost has two components, as in a Cobb-Douglas function (Dowling 1990:213-14): non-labor cost and labor cost. The first component equals the length of the trip multiplied by the sum of k1 and x[1]:

   > cn := k4*(k1 + x[1]); # non-labor cost, entire trip

cn := 200 + \frac{3}{20} v^{8/5}

   > plot(cn, v=50..90, thickness = 3, labels = [speed, cost], title
   = `Fig.  1:  Non-labor cost as function of speed`);

The second cost component equals the driver’s hourly wage multiplied by the amount of time required for the trip, which is the trip length divided by the speed:

   > cl := k3*(k4/v); # labor cost, entire trip

cl := \frac{22290}{v}

   > plot(cl, v=50..90, thickness = 3, labels = [speed, cost], title
   = `Fig.  2:  Labor cost as function of speed`);

Examine non-labor costs and labor costs together, as functions of speed, on a single plot. When we set out to find the speed that minimizes costs, we shall realize that this is a speed for which non-labor costs are increasing at the same rate as labor costs are decreasing.

   > plot({cn, cl}, v=50..90, thickness = 3, labels = [speed, cost],
   title = `Fig.  3:  cn and cl as function of speed`);

Finally, we obtain the sum of cn and cl, which gives us the total cost:

   > ct := cn + cl; #total cost, entire trip

ct := 200 + \frac{3}{20} v^{8/5} + \frac{22290}{v}

   > plot(ct, v=50..90, thickness = 3, labels = [speed, cost], title
   = `Fig.  4:  Total cost as function of speed`);

Dynamics

In order to analyze the socio-ecological dynamics of the truck-transportation situation as defined thus far, we begin by obtaining a derivative as follows:

   > Diff(ct, v) = diff(ct, v);

\frac{∂}{∂v} (200 + \frac{3}{20} v^{8/5} + \frac{22290}{v}) = \frac{6}{25} v^{3/5} − \frac{22290}{v^{2}}

This expression gives the rate of change of cost, relative to speed. We can use it to find the speed that minimizes total costs; this speed is often very high—over 80 m.p.h. in this initial simulation—and it is sometimes considerably higher.

   > sols := solve(diff(ct, v) = 0, v):  sols[1]; evalf(", 4);

92875^{5/13}

81.42

Perhaps more realistically, one could ask how much incentive there would be to increase one’s speed from, say, 60 or 70 m.p.h. to any given higher level. That is, how much would costs for each trip drop for each mile-per-hour added to one’s speed, starting at a relatively safe speed? Here, we need to solve the derivative for v = 60 and v = 70. Adjacent values may be substituted, for experimental purposes.

   > k5 := 60:  k6 := 70:
   > subs(v = k5, diff(ct, v)):  evalf(", 3); subs(v = k6, diff(ct,
   v)):  evalf(", 3);

−3.38
−1.48

These solutions imply that there is a strong incentive for going faster than 60 m.p.h.—$3.38 can be shaved from total-trip cost for each additional mile per hour. At higher speeds, incentives are weaker.

Adaptation and Social Control

In this example, it appears that the tendency to race for loading docks, as described by Ouellet, could be exploited by unscrupulous firms as a way of reducing costs: Any factor that causes drivers to increase speed toward the minimal-cost operating speed, which may be very high, will reduce costs for the trucking firm. Suppose, however, that these cost-reduction strategies tend to get drivers and firms into trouble with the police and highway patrol. This contingency adds to costs. Estimate these costs on a miles-per-hour basis for all speeds in excess of what we might call the de facto speed limit—the speed where the police start writing tickets.

For now, there are two decisions about the sanction system: First, what is the probability of a speeding ticket on a given trip, when one exceeds the de facto speed limit? Second, what is the severity of the sanction, that is, the cost of speeding tickets, for each m.p.h. in excess of the de facto limit?

Social scientists who write about deterrence usually distinguish among four aspects of punishment: probability, severity, celerity (speed), and saliency (awareness of prior warnings or prior instances of punishment). How could all four of these factors be written into a simulation? What is the relative impact of, say, a 10 per cent increase in the probability of punishment versus a plausible increase in the severity of it? We address these questions in an extended version of this paper.

Sanctions: I

We begin working toward a resolution of these problems by writing a new cost function, one that will take into account our costs as already established but will also allow for increased costs due to traffic citations. Initially, we assume a fixed probability for traffic citations, regardless of the degree to which speed exceeds the de facto speed limit. The assumption is based on the idea that excessive speeders make special efforts to avoid detection.

> k7 := 1/10:  # probability of receiving a speeding ticket
> k8 := 9:  # sanction severity:  cost of speeding ticket, for
each m.p.h.  excess
> k9 := 75:  # the de facto speed limit
> cc := k7*k8*(v - k9); cn; cl;

cc := \frac{9}{10} v − \frac{135}{2}

200 + \frac{3}{20} v^{8/5}

\frac{22290}{v}

> ctt := cn + cl + cc; # total cost, including impact of sanction
system

ctt := \frac{265}{2} + \frac{3}{20} v^{8/5} + \frac{22290}{v} + \frac{9}{10} v

> plot({ct, ctt}, v=k9..90, thickness = 3, labels = [speed, cost],
title = `Fig.  5:  Excess operating costs due to sanction system,
I`, titlefont=[TIMES, ROMAN, 9]);

How effective is our sanction system? If the region located between these two curves, and ranging from the de facto speed limit to, say, 90 m.p.h., were considered a “braking factor,” then we could integrate through the region as a way of assessing the weight of this factor.

> Digits := 7:  Int(ctt, v = k9..90) = int(ctt, v); i := int(ctt,
v=k9..90):

∫_{75}^{90} \frac{265}{2} + \frac{3}{20} v^{8/5} + \frac{22290}{v} + \frac{9}{10} v dv = \frac{265}{2} v + \frac{3}{52} v^{13/5} + 22290 ln(v) + \frac{9}{20} v^{2}

> evalf(", 6);

9789.82

> Int(ct, v = k9..90) = int(ct, v); j := int(ct, v=k9..90):  evalf(",
6);

∫_{75}^{90}200 + \frac{3}{20} v^{8/5} + \frac{22290}{v} dv = 200 v + \frac{3}{52} v^{13/5} + 22290 ln(v)

9688.52

> weight := i - j; evalf(", 5);

weight := \frac{405}{4}

101.25

This does not seem to be a very heavy weight, but all is relative. How could we make it heavier? What is the relative impact of sanction probability and sanction severity on the braking factor? In a later installment, we shall address this question.

Reference:

Dowling, Edward T. 1990. Calculus for business, economics, and the social sciences. New York: McGraw-Hill.

Ouellet, Lawrence J. 1994. Pedal to the metal. Philadelphia: Temple University Press.